Pack

The use of pack is the most common form of managing the placement of widgets. The basic usage is

$widget->pack( [ option => value ] );

Although pack has some reasonable defaults to the options, often you will want to specify some of these explicitly for a better look. Consider the following widgets:

#!perl
# file pack1.pl
use Tk;
use strict;
use warnings;
my $mw = MainWindow->new;
$mw->title('Pack Example');
my $title = $mw->Label(-text => 'Example of packing several widgets');
my $cb1 = $mw->Checkbutton(-text => 'Checkbutton 1');
my $button = $mw->Button(-text => 'A Button');
my $label = $mw->Label(-text => 'A Label');
my $cb2 = $mw->Checkbutton(-text => 'Checkbutton 2');
my $exit = $mw->Button(-text => 'Exit',
                       -command => [$mw => 'destroy']);
$title->pack;
$cb1->pack;
$button->pack;
$label->pack;
$cb2->pack;
$exit->pack;
MainLoop;

which is illustrated in the figure below.

Figure 2.4: Example of the use of pack

When pack encounters two or more widgets that are packed without options, it arranges them according to the defaults. The order that the widgets are packed is crucial in this regard - if a widget A is packed ahead of widget B, widget A gets preference. For example, if we change the pack order in the above program from

$title->pack;
$cb1->pack;
$button->pack;
$label->pack;
$cb2->pack;
$exit->pack;

to

$exit->pack;
$button->pack;
$title->pack;
$label->pack;
$cb2->pack;
$cb1->pack;

the window appears as below.

Figure 2.5: A second example of the use of pack

Thus, you can change the appearance of the window by adjusting the order that widgets are packed. The appearance can also be changed by supplying pack with various options; those available, as appears in the Tk documentation, are listed below.

• -after = > $other
  $other must be another window. Use its master as the master for the slave, and insert the slave just after $other in the packing order.

• -anchor = > anchor
  The anchor must be a valid anchor position such as n or sw; it specifies where to position each slave in its parcel. Defaults to center.

• -before = > $other
  $other must be another window. Use its master as the master for the slave, and insert the slave just before $other in the packing order.

• -expand = > boolean
  This specifies whether the slave should be expanded to consume extra space in its master. It may have any proper boolean value, such as 1 or no. Defaults to 0.

• -fill = > style
  If a slave's parcel is larger than its requested dimensions, this option may be used to stretch the slave. The style must have one of the following values:
  • none
    Give the slave its requested dimensions plus any internal padding requested with -ipadx or -ipady. This is the default.

  • x
    Stretch the slave horizontally to fill the entire width of its parcel (except leave external padding as specified by -padx).

  • y
    Stretch the slave vertically to fill the entire height of its parcel (except leave external padding as specified by -pady).

  • both
    Stretch the slave both horizontally and vertically.
• -in = > $master
  Insert the slave(s) at the end of the packing order for the master window given by $master.

• -ipadx = > amount
  The amount specifies how much horizontal internal padding to leave on each side of the slave(s). The amount must be a valid screen distance, such as 2 or .5c. It defaults to 0.

• -ipady = > amount
  The amount specifies how much vertical internal padding to leave on each side of the slave(s). The amount defaults to 0.

• -padx = > amount
  The amount specifies how much horizontal external padding to leave on each side of the slave(s). The amount defaults to 0.

• -pady = > amount
  The amount specifies how much vertical external padding to leave on each side of the slave(s). The amount defaults to 0.

• -side = > side
  This specifies which side of the master the slave(s) will be packed against. Must be left, right, top, or bottom. This defaults to top.

These options can be used to provide us with greater control over where to place the widgets; for example, the following program

#!perl
# file pack2.pl
use Tk;
use strict;
use warnings;
my $mw = MainWindow->new;
$mw->title('Pack Example');
my $title = $mw->Label(-text => 'Example of packing several widgets');
my $cb1 = $mw->Checkbutton(-text => 'Checkbutton 1');
my $button = $mw->Button(-text => 'A Button');
my $label = $mw->Label(-text => 'A Label');
my $cb2 = $mw->Checkbutton(-text => 'Checkbutton 2');
my $exit = $mw->Button(-text => 'Exit',
                       -command => [$mw => 'destroy']);
$exit->pack(-side => 'bottom',
            -expand => 1,
            -fill => 'x',
           );
$title->pack(-side => 'top',
             -expand => 1,
             -fill => 'x',
            );
$cb1->pack(-side => 'left');
$cb2->pack(-side => 'right');
$button->pack(-side => 'top');
$label->pack(-side => 'bottom');
MainLoop;

produces the following output:

Figure 2.6: A third example of the use of pack

We will see in later chapters when discussing various applications the use of some of the other pack options. As with most of programming, it is mainly through experience that a good understanding of these options will be gained.